package  
{
	import flash.display.Sprite;
 
	public class Test extends Sprite 
	{
		private const AMOUNT:int = 1000;
		private var vector:Vector.<ValueObject>; 
		private var linkedList:LinkedValueObject;
		private var text:String;
 
 
		public function Test()
		{
			var i:int;
 
			// create Vector
			i = AMOUNT;
			vector = new Vector.<ValueObject>();
			while (i--) 
			{
				vector.push(new ValueObject("text" + i));
			}
 
			// create linked list
			i = AMOUNT -1;
			linkedList = new LinkedValueObject("text" + i);
			var n:LinkedValueObject = linkedList;
			while (i--) 
			{
				n.link = new LinkedValueObject("text" + i);
				n = n.link;
			}
 
			trace(new PerformanceComparison(AMOUNT, test1, test2, test3).start());
		}
 
		protected function test1():void 
		{
			var vo:ValueObject;
			for each (vo in vector) {
				text = vo.text;
			}
		}
 
		protected function test2():void 
		{
			var i:int;
			for (i = 0; i < AMOUNT; i++) {
				text = vector[i].text; 
			}
		}
 
		protected function test3():void 
		{
			var vo:LinkedValueObject = linkedList;
			while (vo != null) 
			{
				text = vo.text;
				vo = vo.link;
			}
		}
	}
}
 
internal class ValueObject
{
	public var text:String;
 
	function ValueObject(text:String) 
	{
		this.text = text;
	}
}
 
internal class LinkedValueObject
{
	public var text:String;
	public var link:LinkedValueObject;
 
	function LinkedValueObject(text:String) 
	{
		this.text = text;
	}	
}