package  
{
	import flash.display.Sprite;
 
	public class Test extends Sprite 
	{
		private const TEXT : String = "ABCDEFGHIJKLMNOPQRSTUVWXYZ";
		private const NUMBER : Number = 1234567890;
 
		public function Test()
		{
			trace(new PerformanceComparison(1000000, test1, test2, test3, test4).start());
		}
 
		private function test1():void 
		{
			test1helper(new ValueObject);
		}
 
		private function test2():void 
		{
			test2helper(new ValueObject);
		}
 
		private function test3():void 
		{
			test3helper(new ValueObject);
		}
 
		private function test4():void 
		{
			test4helper(new ValueObject);
		}
 
		/**
		 * Apply directly
		 */
		private function test1helper(obj : ValueObject) : void {
			obj.text = TEXT;
			obj.number = NUMBER;  
		}
 
		/**
		 * Apply with Interface
		 */
		private function test2helper(obj : IValueObject) : void {
			obj.text = TEXT;
			obj.number = NUMBER; 
		}
 
		/**
		 * Apply with TypeCast
		 */
		private function test3helper(obj : Object) : void {
			(obj as ValueObject).text = TEXT;
			(obj as ValueObject).number = NUMBER;
		}
 
		/**
		 * Apply with TypeCast to Interface
		 */
		private function test4helper(obj : Object) : void {
			(obj as IValueObject).text = TEXT;
			(obj as IValueObject).number = NUMBER;
		}
	}
}
 
internal interface IValueObject {
	function get number() : Number;
 
	function set number(n:Number) : void;
 
	function get text() : String;
 
	function set text(str:String) : void;
}
 
internal class ValueObject implements IValueObject {
	private var _number : Number;
	private var _text : String;
 
	public function get number() : Number {
		return _number;
	}
 
	public function get text() : String {
		return _text;
	}
 
	public function set number(n : Number) : void {
		_number = n;
	}
 
	public function set text(str : String) : void {
		_text = str;
	}
}